Add tsx provider, closes #330

3 files changed, 203 insertions, 0 deletions

diff --git a/after/ftplugin/tsx.vim b/after/ftplugin/tsx.vim
new file mode 100644
index 00000000..62112bba
--- /dev/null
+++ b/after/ftplugin/tsx.vim
@@ -0,0 +1,21 @@
+if exists('g:polyglot_disabled') && index(g:polyglot_disabled, 'tsx') != -1
+  finish
+endif
+
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Vim ftplugin file
+"
+" Language: TSX (JavaScript)
+" Maintainer: Ian Ker-Seymer <i.kerseymer@gmail.com>
+" Depends: leafgarland/typescript-vim
+"
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+
+" modified from html.vim
+if exists("loaded_matchit")
+  let b:match_ignorecase = 0
+  let b:match_words = '(:),\[:\],{:},<:>,' .
+        \ '<\@<=\([^/][^ \t>]*\)[^>]*\%(>\|$\):<\@<=/\1>'
+endif
+
+setlocal suffixesadd+=.tsx
diff --git a/after/indent/tsx.vim b/after/indent/tsx.vim
new file mode 100644
index 00000000..a74c7bef
--- /dev/null
+++ b/after/indent/tsx.vim
@@ -0,0 +1,95 @@
+if exists('g:polyglot_disabled') && index(g:polyglot_disabled, 'tsx') != -1
+  finish
+endif
+
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Vim indent file
+"
+" Language: TSX (JavaScript)
+" Maintainer: Ian Ker-Seymer <i.kerseymer@gmail.com>
+" Depends: pangloss/vim-typescript
+"
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+
+" Prologue; load in XML indentation.
+if exists('b:did_indent')
+  let s:did_indent=b:did_indent
+  unlet b:did_indent
+endif
+exe 'runtime! indent/xml.vim'
+if exists('s:did_indent')
+  let b:did_indent=s:did_indent
+endif
+
+setlocal indentexpr=GetTsxIndent()
+
+" TS indentkeys
+setlocal indentkeys=0{,0},0),0],0\,,!^F,o,O,e
+" XML indentkeys
+setlocal indentkeys+=*<Return>,<>>,<<>,/
+
+" Self-closing tag regex.
+let s:sctag = '^\s*\/>\s*;\='
+
+" Get all syntax types at the beginning of a given line.
+fu! SynSOL(lnum)
+  return map(synstack(a:lnum, 1), 'synIDattr(v:val, "name")')
+endfu
+
+" Get all syntax types at the end of a given line.
+fu! SynEOL(lnum)
+  let lnum = prevnonblank(a:lnum)
+  let col = strlen(getline(lnum))
+  return map(synstack(lnum, col), 'synIDattr(v:val, "name")')
+endfu
+
+" Check if a syntax attribute is XMLish.
+fu! SynAttrXMLish(synattr)
+  return a:synattr =~ "^xml" || a:synattr =~ "^tsx"
+endfu
+
+" Check if a synstack is XMLish (i.e., has an XMLish last attribute).
+fu! SynXMLish(syns)
+  return SynAttrXMLish(get(a:syns, -1))
+endfu
+
+" Check if a synstack has any XMLish attribute.
+fu! SynXMLishAny(syns)
+  for synattr in a:syns
+    if SynAttrXMLish(synattr)
+      return 1
+    endif
+  endfor
+  return 0
+endfu
+
+" Check if a synstack denotes the end of a TSX block.
+fu! SynTSXBlockEnd(syns)
+  return get(a:syns, -1) == 'tsBraces' && SynAttrXMLish(get(a:syns, -2))
+endfu
+
+" Cleverly mix TS and XML indentation.
+fu! GetTsxIndent()
+  let cursyn  = SynSOL(v:lnum)
+  let prevsyn = SynEOL(v:lnum - 1)
+
+  " Use XML indenting if the syntax at the end of the previous line was either
+  " TSX or was the closing brace of a tsBlock whose parent syntax was TSX.
+  if (SynXMLish(prevsyn) || SynTSXBlockEnd(prevsyn)) && SynXMLishAny(cursyn)
+    let ind = XmlIndentGet(v:lnum, 0)
+
+    " Align '/>' with '<' for multiline self-closing tags.
+    if getline(v:lnum) =~? s:sctag
+      let ind = ind - &sw
+    endif
+
+    " Then correct the indentation of any TSX following '/>'.
+    if getline(v:lnum - 1) =~? s:sctag
+      let ind = ind + &sw
+    endif
+  else
+    let ind = GetTypescriptIndent()
+  endif
+
+  return ind
+endfu
diff --git a/after/syntax/tsx.vim b/after/syntax/tsx.vim
new file mode 100644
index 00000000..05bfc9ea
--- /dev/null
+++ b/after/syntax/tsx.vim
@@ -0,0 +1,87 @@
+if exists('g:polyglot_disabled') && index(g:polyglot_disabled, 'tsx') != -1
+  finish
+endif
+
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+" Vim syntax file
+"
+" Language: TSX (JavaScript)
+" Maintainer: Ian Ker-Seymer <i.kerseymer@gmail.com>
+" Depends: leafgarland/typescript-vim
+"
+"""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""""
+
+if exists('b:current_syntax')
+  let s:current_syntax=b:current_syntax
+  unlet b:current_syntax
+endif
+
+syn include @XMLSyntax syntax/xml.vim
+
+if exists('s:current_syntax')
+  let b:current_syntax=s:current_syntax
+endif
+
+syn region embeddedTs
+      \ matchgroup=NONE
+      \ start=+{+
+      \ end=+}+
+      \ contains=@Spell,@typescriptAll,xmlEntity,tsxRegion
+      \ contained
+
+" Add embeddedTs to everything where xmlString is used to allow for
+" both string highlighting and @typescriptAll highlighting
+syn region   xmlTag
+      \ matchgroup=xmlTag start=+<[^ /!?<>"']\@=+
+      \ matchgroup=xmlTag end=+>+
+      \ contained
+      \ contains=xmlError,xmlTagName,xmlAttrib,xmlEqual,xmlString,@xmlStartTagHook,embeddedTs
+
+syn region xmlProcessing
+      \ matchgroup=xmlProcessingDelim
+      \ start="<?"
+      \ end="?>"
+      \ contains=xmlAttrib,xmlEqual,xmlString,embeddedTs
+
+
+if exists('g:xml_syntax_folding')
+  " DTD -- we use dtd.vim here
+  syn region  xmlDocType matchgroup=xmlDocTypeDecl
+        \ start="<!DOCTYPE"he=s+2,rs=s+2
+        \ end=">"
+        \ fold
+        \ contains=xmlDocTypeKeyword,xmlInlineDTD,xmlString,embeddedTs
+else
+  syn region  xmlDocType matchgroup=xmlDocTypeDecl
+        \ start="<!DOCTYPE"he=s+2,rs=s+2
+        \ end=">"
+        \ contains=xmlDocTypeKeyword,xmlInlineDTD,xmlString,embeddedTs
+endif
+
+
+if exists('g:xml_syntax_folding')
+  syn region xmlTag
+        \ matchgroup=xmlTag start=+<[^ /!?<>"']\@=+
+        \ matchgroup=xmlTag end=+>+
+        \ contained
+        \ contains=xmlError,xmlTagName,xmlAttrib,xmlEqual,xmlString,@xmlStartTagHook,embeddedTs
+else
+  syn region xmlTag
+        \ matchgroup=xmlTag start=+<[^ /!?<>"']\@=+
+        \ matchgroup=xmlTag end=+>+
+        \ contains=xmlError,xmlTagName,xmlAttrib,xmlEqual,xmlString,@xmlStartTagHook,embeddedTs
+endif
+
+
+syn region tsxRegion
+      \ contains=@Spell,@XMLSyntax,tsxRegion,@typescriptAll
+      \ start=+\%(<\|\w\)\@<!<\z([a-zA-Z][a-zA-Z0-9:\-.]*\)+
+      \ skip=+<!--\_.\{-}-->+
+      \ end=+</\z1\_\s\{-}>+
+      \ end=+/>+
+      \ keepend
+      \ extend
+
+hi def link embeddedTs NONE
+
+syn cluster @typescriptAll add=tsxRegion