From bc9757916ed09763d96283ee62dbed58bd713a11 Mon Sep 17 00:00:00 2001
From: Adam Stankiewicz <sheerun@sher.pl>
Date: Tue, 6 Oct 2020 18:54:19 +0200
Subject: Add all vim filetypes

---
 ftplugin/nsis.vim | 47 +++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 47 insertions(+)
 create mode 100644 ftplugin/nsis.vim

(limited to 'ftplugin/nsis.vim')

diff --git a/ftplugin/nsis.vim b/ftplugin/nsis.vim
new file mode 100644
index 00000000..8820f066
--- /dev/null
+++ b/ftplugin/nsis.vim
@@ -0,0 +1,47 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'nsis') == -1
+
+" Vim ftplugin file
+" Language:		NSIS script
+" Maintainer:		Ken Takata
+" URL:			https://github.com/k-takata/vim-nsis
+" Previous Maintainer:	Nikolai Weibull <now@bitwi.se>
+" Last Change:		2018-01-26
+
+if exists("b:did_ftplugin")
+  finish
+endif
+
+let s:cpo_save = &cpo
+set cpo&vim
+
+let b:did_ftplugin = 1
+
+let b:undo_ftplugin = "setl com< cms< fo< def< inc<"
+      \ " | unlet! b:match_ignorecase b:match_words"
+
+setlocal comments=s1:/*,mb:*,ex:*/,b:#,:; commentstring=;\ %s
+setlocal formatoptions-=t formatoptions+=croql
+setlocal define=^\\s*!define\\%(\\%(utc\\)\\=date\\|math\\)\\=
+setlocal include=^\\s*!include\\%(/NONFATAL\\)\\=
+
+if exists("loaded_matchit")
+  let b:match_ignorecase = 1
+  let b:match_words =
+	\ '\${\%(If\|IfNot\|Unless\)}:\${\%(Else\|ElseIf\|ElseIfNot\|ElseUnless\)}:\${\%(EndIf\|EndUnless\)},' .
+	\ '\${Select}:\${EndSelect},' .
+	\ '\${Switch}:\${EndSwitch},' .
+	\ '\${\%(Do\|DoWhile\|DoUntil\)}:\${\%(Loop\|LoopWhile\|LoopUntil\)},' .
+	\ '\${\%(For\|ForEach\)}:\${Next},' .
+	\ '\<Function\>:\<FunctionEnd\>,' .
+	\ '\<Section\>:\<SectionEnd\>,' .
+	\ '\<SectionGroup\>:\<SectionGroupEnd\>,' .
+	\ '\<PageEx\>:\<PageExEnd\>,' .
+	\ '\${MementoSection}:\${MementoSectionEnd},' .
+	\ '!if\%(\%(macro\)\?n\?def\)\?\>:!else\>:!endif\>,' .
+	\ '!macro\>:!macroend\>'
+endif
+
+let &cpo = s:cpo_save
+unlet s:cpo_save
+
+endif
-- 
cgit v1.2.3