From 5b77877888162f4e415fe9a7b8c5e9fb5dfb6ee1 Mon Sep 17 00:00:00 2001
From: Adam Stankiewicz <sheerun@sher.pl>
Date: Wed, 27 Sep 2017 20:43:42 +0200
Subject: Add syntax files from upstream vim repository

---
 ftplugin/aspvbs.vim | 64 +++++++++++++++++++++++++++++++++++++++++++++++++++++
 1 file changed, 64 insertions(+)
 create mode 100644 ftplugin/aspvbs.vim

(limited to 'ftplugin/aspvbs.vim')

diff --git a/ftplugin/aspvbs.vim b/ftplugin/aspvbs.vim
new file mode 100644
index 00000000..881e579c
--- /dev/null
+++ b/ftplugin/aspvbs.vim
@@ -0,0 +1,64 @@
+if !exists('g:polyglot_disabled') || index(g:polyglot_disabled, 'vim') == -1
+  
+" Vim filetype plugin file
+" Language:	aspvbs
+" Maintainer:	Dan Sharp <dwsharp at users dot sourceforge dot net>
+" Last Changed: 20 Jan 2009
+" URL:		http://dwsharp.users.sourceforge.net/vim/ftplugin
+
+if exists("b:did_ftplugin") | finish | endif
+
+" Make sure the continuation lines below do not cause problems in
+" compatibility mode.
+let s:save_cpo = &cpo
+set cpo-=C
+
+" Define some defaults in case the included ftplugins don't set them.
+let s:undo_ftplugin = ""
+let s:browsefilter = "HTML Files (*.html, *.htm)\t*.htm*\n" .
+	    \	     "All Files (*.*)\t*.*\n"
+let s:match_words = ""
+
+runtime! ftplugin/html.vim ftplugin/html_*.vim ftplugin/html/*.vim
+let b:did_ftplugin = 1
+
+" Override our defaults if these were set by an included ftplugin.
+if exists("b:undo_ftplugin")
+    let s:undo_ftplugin = b:undo_ftplugin
+endif
+if exists("b:browsefilter")
+    let s:browsefilter = b:browsefilter
+endif
+if exists("b:match_words")
+    let s:match_words = b:match_words
+endif
+
+" ASP:  Active Server Pages (with Visual Basic Script)
+" thanks to Gontran BAERTS
+if exists("loaded_matchit")
+  let s:notend = '\%(\<end\s\+\)\@<!'
+  let b:match_ignorecase = 1
+  let b:match_words =
+  \ s:notend . '\<if\>\%(.\{-}then\s\+\w\)\@!:\<elseif\>:^\s*\<else\>:\<end\s\+\<if\>,' .
+  \ s:notend . '\<select\s\+case\>:\<case\>:\<case\s\+else\>:\<end\s\+select\>,' .
+  \ '^\s*\<sub\>:\<end\s\+sub\>,' .
+  \ '^\s*\<function\>:\<end\s\+function\>,' .
+  \ '\<class\>:\<end\s\+class\>,' .
+  \ '^\s*\<do\>:\<loop\>,' .
+  \ '^\s*\<for\>:\<next\>,' .
+  \ '\<while\>:\<wend\>,' .
+  \ s:match_words
+endif
+
+" Change the :browse e filter to primarily show ASP-related files.
+if has("gui_win32")
+    let  b:browsefilter="ASP Files (*.asp)\t*.asp\n" . s:browsefilter
+endif
+
+let b:undo_ftplugin = "unlet! b:match_words b:match_ignorecase b:browsefilter | " . s:undo_ftplugin
+
+" Restore the saved compatibility options.
+let &cpo = s:save_cpo
+unlet s:save_cpo
+
+endif
-- 
cgit v1.2.3